ファイルシステムオブジェクトによるファイル移動

このページでは以下のファイル移動メソッドについて説明します。

• fso.MoveFile（※1）
• file.Move

使い分けの判断基準

1つのファイルを移動させる場合

どちらのメソッドを使用しても機能的には同じになりますので、そのときの処理内容により判断します。通常、処理の途中でファイルオブジェクトを取得済みであれば file.Move、ファイルオブジェクトを取得していないのであれば fso.MoveFile を使用します。

複数のファイルを移動させる場合

fso.MoveFile を使用します。移動元のファイル群を上記ワイルドカードで表現する必要があります。ワイルドカードで表現できない場合は file.Move でファイルを1つずつ移動させるしかありません。

fso.MoveFileの使用方法

引数に移動元、移動先のファイルパスを指定してファイルの移動を行います。

fso.MoveFile Source, Destination

fso.MoveFileの使用例

1つのファイルを移動する

数 Destination に既存フォルダ名（パスの区切り文字で終わる）を指定します。 以下の例では vba フォルダ内にある test.txt を backup フォルダ内に移動します。

Sub sample_fs023_01()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim strSrc      As String   '移動元
    Dim strDst      As String   '移動先

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    '移動元ファイルパスの設定
    strSrc = "C:¥Users¥xxx¥Desktop¥vba¥test.txt"
    '移動先フォルダパスの設定
    strDst = "C:¥Users¥xxx¥Desktop¥backup¥"

    'ファイルの移動
    fso.MoveFile strSrc, strDst

    'オブジェクト変数のクリア
    Set fso = Nothing
End Sub

  Setステートメント

1つのファイルを移動する（ファイル名変更あり）

引数 Destination に移動後のファイル名を指定します。以下の例では、vba フォルダ内にある test.txt を backup フォルダ内に移動し、さらに、ファイル名を test_130817.txt へ変更します。

Sub sample_fs023_02()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim strSrc      As String   '移動元
    Dim strDst      As String   '移動先

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    '移動元ファイルパスの設定
    strSrc = "C:¥Users¥xxx¥Desktop¥vba¥test.txt"
    '移動先ファイルパスの設定（ファイル名変更）
    strDst = "C:¥Users¥xxx¥Desktop¥backup¥test_130817.txt"

    'ファイルの移動
    fso.MoveFile strSrc, strDst

    'オブジェクト変数のクリア
    Set fso = Nothing
End Sub

  Setステートメント

複数のファイルを1命令で移動する

引数 Source にワイルドカードを使用して移動したいファイル群を表現します。以下の例では、vba フォルダ内にあるテキストファイルをすべて backup フォルダ内へ移動します。

Sub sample_fs023_03()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim strSrc      As String   '移動元
    Dim strDst      As String   '移動先

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'ワイルドカードを使用して移動元ファイルパスの設定
    strSrc = "C:¥Users¥xxx¥Desktop¥vba¥*.txt"
    '移動先フォルダパスの設定
    strDst = "C:¥Users¥xxx¥Desktop¥backup¥"

    'ファイルの移動
    fso.MoveFile strSrc, strDst

    'オブジェクト変数のクリア
    Set fso = Nothing
End Sub

  Setステートメント

file.Moveの使用方法

ファイルオブジェクト内に移動元のファイルパス情報を持っているので、引数に指定するのは移動先のファイルパスのみです。 その他の使用方法は fso.MoveFile に同じです。

file.Move Destination

file.Moveの使用例

1つのファイルを移動する

引数 Destination に既存フォルダ名（パスの区切り文字で終わる）を指定します。以下の例では vba フォルダ内にある test.txt を backup フォルダ内に移動します。

Sub sample_fs023_04()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim fileObj     As Object   'ファイルオブジェクト

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'ファイルオブジェクト取得
    Set fileObj = fso.GetFile("C:¥Users¥xxx¥Desktop¥vba¥test.txt")

    'ファイルの移動
    fileObj.Move "C:¥Users¥xxx¥Desktop¥backup¥"

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set fileObj = Nothing
End Sub

 fso.GetFile Setステートメント

1つのファイルを移動する（ファイル名変更あり）

引数 Destination に移動後のファイル名を指定します。以下の例では、vba フォルダ内にある test.txt を backup フォルダ内に移動し、さらに、ファイル名を test_130817.txt へ変更します。

Sub sample_fs023_05()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim fileObj     As Object   'ファイルオブジェクト

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'ファイルオブジェクト取得
    Set fileObj = fso.GetFile("C:¥Users¥xxx¥Desktop¥vba¥test.txt")

    'ファイルの移動
    fileObj.Move "C:¥Users¥xxx¥Desktop¥backup¥test_130817.txt"

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set fileObj = Nothing
End Sub

 fso.GetFile Setステートメント

フォルダ内の複数ファイルを1つずつ移動する

指定されたフォルダ内のファイルのうち、Like演算子 を使用して、あるファイル名パターンにマッチするものだけを移動させる例です。以下の例では、ファイル名が”a”と4ケタの数字からなるテキストファイルを backup フォルダへ移動します。

Sub sample_fs023_06()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim folderObj   As Object   'フォルダオブジェクト
    Dim fileObj     As Object   'ファイルオブジェクト

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'フォルダオブジェクト取得
    Set folderObj = fso.GetFolder("C:¥Users¥xxx¥Desktop¥vba")

    For Each fileObj In folderObj.Files
        'ファイル名判定
        If fileObj.Name Like "a####.txt" Then
            'ファイルの移動
            fileObj.Move "C:¥Users¥xxx¥Desktop¥backup¥"
        End If
    Next

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set folderObj = Nothing
    Set fileObj = Nothing
End Sub

 fso.GetFolder  For Each…Next  Like 演算子  Setステートメント

以下の２つの図はマクロ実行前のvbaフォルダとbackupフォルダの状態です。

上記サンプルマクロを実行すると、aから始まる数値4桁のテキストファイル2つがbackupフォルダに移動したことがわかります。

 
ファイルシステムオブジェクトのプロパティ・メソッド
ファイルシステムオブジェクトによるフォルダ移動