セル書式（フォント）の設定方法

このページでは、セルの書式設定画面の配置タブに対応するプロパティについて説明します。

～目次～

配置に関するプロパティの設定

配置に関するプロパティの設定

Sub sample6_15()
    With Range("A1").Font
        'フォント名
        .Name = "ＭＳ Ｐゴシック"
        'フォントスタイル
        .FontStyle = "標準"
        'サイズ
        .Size = 12
        '下線
        .Underline = xlUnderlineStyleSingle
        'フォント色
        .Color = vbRed
        '取消線
        .Strikethrough = False
        '上付き
        .Superscript = False
        '下付き
        .Subscript = False
    End With
End Sub

フォント名 – Font.Name, サイズ – Font.Size プロパティ

フォント名には、”ＭＳ　Ｐゴシック” や “ＭＳ　Ｐ明朝” などのフォント名を指定します。サイズにはポイント単位で整数値を設定します。

フォントスタイル – FontStyle プロパティ

フォントスタイルは FontStyle プロパティに下表の定数を設定することで変更することができます。ただ、FontStyle は Font.Bold および Font.Italic で代用できますので、使いやすい方を選ぶとよいでしょう。

プロパティ	定数	説明
Font.Style	“標準”（または値をクリア）	標準
	“斜体” または “Italic”	斜体
	“太字” または “Bold”	太字
	“太字斜体” または “Bold Italic”	太字＋斜体 ※間の空白は半角

Sub sample6_16()
    With Range("A1")
        .Value = "FontStyleに「太字 斜体」を設定した場合"
        .Font.FontStyle = "太字 斜体"
    End With

    With Range("A3")
        .Value = "FontStyleに「Bold Italic」を設定した場合"
        .Font.FontStyle = "Bold Italic"
    End With

    With Range("A5")
        .Value = "Bold、ItalicにTrueを設定した場合"
        .Font.Bold = True
        .Font.Italic = True
    End With
End Sub

下線 – Font.Underline プロパティ

下線はFont.Underlineプロパティに下表の定数を設定することで変更することができます。

プロパティ	定数	説明
Font.Underline	xlNone またはxlUnderlineStyleNone	なし
	xlUnderlineStyleSingle	下線
	xlUnderlineStyleDouble	二重下線
	xlUnderlineStyleSingleAccounting	下線（会計）
	xlUnderlineStyleDoubleAccounting	二重下線（会計）

Sub sample6_17()
    With Range("A1")
        .Value = "下線　AaＡａあぁアァ亜宇"
        .Font.Underline = xlUnderlineStyleSingle
    End With

    With Range("A3")
        .Value = "二重下線　AaＡａあぁアァ亜宇"
        .Font.Underline = xlUnderlineStyleDouble
    End With

    With Range("A5")
        .Value = "下線（会計）　AaＡａあぁアァ亜宇"
        .Font.Underline = xlUnderlineStyleSingleAccounting
    End With

    With Range("A7")
        .Value = "二重下線（会計）　AaＡａあぁアァ亜宇"
        .Font.Underline = xlUnderlineStyleDoubleAccounting
    End With
End Sub

フォント色 – Font.Color Font.ColorIndex プロパティ

フォント色はFont.ColorまたはFont.ColorIndexプロパティのどちらかを設定します。それぞれ色の指定の仕方が異なりますので、扱いやすい方を使用しましょう。

Font.Color ・・・色定数またはRGB値で色を指定
Font.ColorIndex ・・・カラーパレットのインデックス値で色を指定
※フォント色を自動設定する場合は定数を指定

プロパティ	定数・値	説明
Font.Color	vbBlack	黒色
	vbRed	赤色
	vbGreen	緑色
	vbBlue	青色
	vbYellow	黄色
	vbMagenta	マゼンタ
	vbCyan	シアン
	vbWhite	白色
	RGB関数の戻り値 ※R,G,Bは0～255の範囲	RGB値（Long型）
Font.ColorIndex	xlAutomatic またはxlColorIndexAutomatic	自動設定 ※上図の”自動”に相当
Font.ColorIndex	1～56の整数値	カラーパレットのインデックス値 ※上図の色配置とは別物

カラーパレットの一覧を作成する

取消線、上付き文字、下付き文字

取消線は Font.Strikethrough プロパティにTrueを設定することで可能になります。
上付き文字は Font.Superscript プロパティにTrueを設定することで可能になります。
下付き文字は Font.Subscript プロパティにTrueを設定することで可能になります。
上付き文字と下付き文字は同時に設定することはできません。

Sub sample6_18()
    With Range("A1")
        .Value = "取消線　AaＡａあぁアァ亜宇"
        .Font.Strikethrough = True
    End With

    With Range("A3")
        .Value = "216 = 65536です。"
        '16(2文字目から2文字分)を上付き文字にします。
        .Characters(2, 2).Font.Superscript = True
    End With

    With Range("A5")
        .Value = "水の化学式はH2Oです。"
        '2(8文字目から1文字分)を下付き文字にします。
        .Characters(8, 1).Font.Subscript = True
    End With
End Sub

フォントの部分設定