OpenTextFileメソッドによるテキストファイル操作

前のページではテキストストリームオブジェクトを取得する3つのメソッドのうち、 CreateTextFile メソッドを使用したテキストファイル操作方法を説明しました。このページではつづいて OpenTextFile メソッドを使用してテキストファイルを読み書きする方法を説明します。

OpenTextFileメソッドの使用方法

OpenTextFile メソッドは ファイルシステムオブジェクトのメンバーメソッドです。引数 FileName には操作対象ファイルのパスを絶対パスか相対パスで指定する必要があります。

fso.OpenTextFile(FileName [, IOMode] [, Create] [, Format])

入力に関する主なプロパティ・メソッド

読み込みモードでテキストストリームオブジェクトを取得した後、以下のプロパティおよびメソッドを使用することで文字列の読み込みなどが可能になります。

※出力に関するプロパティ・メソッドはこの前ページへのリンク先を参照してください。

• tso.Line
  現在のファイルポインタ（行）を取得します。先頭行は 1 となります。 tso.ReadLine メソッドなどを使用するとこの行を読み込みます。
• tso.Column
  現在のカラム位置（行頭からの文字位置）を取得します。 行頭は 1 となります。tso.Read メソッドを使用するとこの位置の文字を読み込みます。
• tso.Read ( Characters )
  ファイルから指定された文字数を読み込みます。 引数 Characters （省略不可）には読み込む文字数を指定します。
• tso.ReadLine
  ファイルから 1 行 (改行文字を除く) を読み込みます。
• tso.ReadAll
  ファイル全体を読み込みます。 ファイルサイズの大きいファイルに対して使用するとメモリを大量に消費し、 処理のパフォーマンスが悪くなる可能性があります。
• tso.Skip ( Characters )
  引数 Characters （省略不可）で指定された文字数の読み込みをスキップします。
• tso.SkipLine
  現在のファイルポインタのある行の読み込みをスキップします。
• tso.AtEndOfStream
  ファイルポインタがファイルの末尾にあるかどうかを True / False で返します。
• tso.AtEndOfLine
  ファイルポインタが行の末尾にあるかどうかを True / False で返します。
• tso.Close
  開いているテキストファイルを閉じます。

OpenTextFileメソッドの使用例

テキストファイルの読込例1

fso.OpenTextFile メソッドを使用して読み込みモードでテキストストリームオブジェクトを取得後、tso.ReadLine メソッドにより1行ずつ読み込む例です。

Sub sample_fs027_01()
    Dim fso         As Object
    Dim tso         As Object
    Dim strPath     As String

    'ファイルシステムオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")
    'ファイルパス
    strPath = "C:\Users\xxxx\Desktop\vba\fs027_01.txt"
    'テキストストリームオブジェクトの取得（読み込みモード）
    Set tso = fso.OpenTextFile(strPath)

    With tso
        Do Until .AtEndOfStream     'ファイル末尾まで繰り返し
            'イミディエイトウィンドウへ読み込み位置と値を表示
            Debug.Print "行 = " & .Line & _
                        "　位置 = " & .Column & _
                        "　値 = " & .ReadLine
        Loop

        .Close  'ファイルのクローズ
    End With

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set tso = Nothing
End Sub

 Do…Loop  Withステートメント  Setステートメント

下図はテスト用の入力ファイルです。

上記サンプルマクロを実行すると、テキストファイルを読み込み、内容をイミディエイトウィンドウへ表示します。

テキストファイルの読込例2

fso.OpenTextFile メソッドを使用して読み込みモードでテキストストリームオブジェクトを取得後、tso.Read メソッドにより1文字ずつ読み込む例です。

以下の例では1行目を読み飛ばし、2行目を1文字ずつ読み込んでイミディエイトウィンドウへ表示します。

Sub sample_fs027_02()
    Dim fso         As Object
    Dim tso         As Object
    Dim strPath     As String

    'ファイルシステムオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")
    'ファイルパス
    strPath = "C:\Users\xxx\Desktop\vba\fs027_01.txt"
    'テキストストリームオブジェクトの取得（読み込みモード）
    Set tso = fso.OpenTextFile(strPath)

    With tso
        .SkipLine   '行のスキップ

        Do Until .AtEndOfLine   '行の末尾まで繰り返し
            'イミディエイトウィンドウへ読み込み位置と値を表示
            Debug.Print "行 = " & .Line & _
                        "　位置 = " & .Column & _
                        "　値 = " & .Read(1)
        Loop

        .Close  'ファイルのクローズ
    End With

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set tso = Nothing
End Sub

 Do…Loop  Withステートメント  Setステートメント

下図はテスト用の入力ファイルです。

上記サンプルマクロを実行すると、テキストファイルを読み込み、内容をイミディエイトウィンドウへ表示します。

既存テキストファイルの追加書込例

fso.OpenTextFile メソッドを使用して追加書き込みモードでテキストストリームオブジェクトを取得後、tso.WriteLine メソッドにより現在日時を追加書き込みする例です。

fso.OpenTextFile メソッドの第2引数は、オブジェクトライブラリへの参照設定をしておくことで、定数“ForAppending”が指定可能になります。

Sub sample_fs027_03()
    Dim fso         As Object
    Dim tso         As Object
    Dim strPath     As String

    'ファイルシステムオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")
    'ファイルパス
    strPath = "C:\Users\xxxx\Desktop\vba\fs027_03.txt"
    'テキストストリームオブジェクトの取得（追加書き込みモード）
    Set tso = fso.OpenTextFile(strPath, 8, True)

    With tso
        .WriteLine Now  '現在日時を追加書き込み
        .Close  'ファイルのクローズ
    End With

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set tso = Nothing
End Sub

 Withステートメント  Setステートメント

下図はテスト用の入力ファイルです。

上記サンプルマクロを実行すると、既存テキストファイルに現在日時を追加書き込みされました。

 
ファイルシステムオブジェクトのプロパティ・メソッド
Openステートメントを使用したテキストファイル読込
Openステートメントを使用したテキストファイル追加書込