セル書式（塗りつぶし効果）の設定方法

このページでは、セルの書式設定画面の塗りつぶしタブの塗りつぶし効果（グラデーション）に対応するプロパティについて説明します。

～目次～

塗りつぶし効果の使用方法
1. 線形グラデーション
2. 四角形グラデーション

塗りつぶし効果の使用方法

グラデーション効果を得るには Interior.Pattern プロパティにグラデーション用の定数を設定します。
その後で、グラデーションの切替ポイントや色の設定を行います。

グラデーションはセルの背景色やパターンと同時に設定することはできません。

線形グラデーション

線形グラデーションを使用するには Interior.Pattern プロパティに xlPatternLinearGradient を設定します。その後、グラデーションの角度（Interior.Gradient.Degree）とグラデーションの切替ポイント（Interior.Gradient.ColorStops）を設定します。

Sub sample6_23()
    'セル背景の線形グラデーション設定
    With Range("B2").Interior
        .Pattern = xlPatternLinearGradient

        With .Gradient
            'グラデーションの角度(0～360°)
            .Degree = 45

            'グラデーションの切替ポイントの設定
            With .ColorStops
                '最初に初期化
                .Clear
                'グラデーションの切替ポイント(0～1)を追加して色を設定
                .Add(0).Color = RGB(255, 128, 204)
                .Add(1).Color = vbBlue
            End With
        End With
    End With
End Sub

四角形グラデーション

四角形グラデーションを使用するには Interior.Pattern プロパティに xlPatternRectangularGradient を設定します。その後、グラデーションの収束先とグラデーションの切替ポイント（Interior.Gradient.ColorStops）を設定します。

Sub sample6_24()
    'セル背景の四角形グラデーション設定
    With Range("B2").Interior
        .Pattern = xlPatternRectangularGradient

        With .Gradient
            'グラデーションの収束先となるポイント(0～1)を設定
            .RectangleTop = 0.4
            .RectangleRight = 0.8
            .RectangleBottom = 0.3
            .RectangleLeft = 0.2

            'グラデーションの切替ポイントの設定
            With .ColorStops
                '最初に初期化
                .Clear
                'グラデーションの切替ポイント(0～1)を追加して色を設定
                .Add(0).ThemeColor = xlThemeColorDark1
                .Add(1).ThemeColor = xlThemeColorAccent1
            End With
        End With
    End With
End Sub

※グラデーションには通常の色（.Color）以外にOffieceのテーマ色（.ThemeColor）が使用できます。

プロパティ	定数	説明
ThemeColor	xlThemeColorDark1	濃色1
	xlThemeColorDark2	濃色2
	xlThemeColorLight1	淡色1
	xlThemeColorLight2	淡色2
	xlThemeColorAccent1	強調1
	xlThemeColorAccent2	強調2
	xlThemeColorAccent3	強調3
	xlThemeColorAccent4	強調4
	xlThemeColorAccent5	強調5
	xlThemeColorAccent6	強調6
	xlThemeColorHyperlink	ハイパーリンク
	xlThemeColorFollowedHyperlink	表示済みハイパーリンク