ファイルシステムオブジェクトによるファイルコピー

このページでは以下のファイルコピーメソッドについて説明します。

• fso.CopyFile（※1）
• file.Copy

使い分けの判断基準

1つのファイルをコピーする場合

どちらのメソッドを使用しても機能的には同じになりますので、そのときの処理内容により判断します。通常、処理の途中でファイルオブジェクトを取得済みであれば file.Copy、ファイルオブジェクトを取得していないのであれば fso.CopyFileを使用します。

複数のファイルをコピーする場合

fso.CopyFileを使用します。コピー元のファイル群を上記ワイルドカードで表現する必要があります。ワイルドカードで表現できない場合は file.Copyでファイルを1つずつコピーするしかありません。

fso.CopyFileの使用方法

引数にコピー元、コピー先のファイルパスを指定してファイルのコピーを行います。 コピー先のファイルを上書きしたくない場合は、引数 OverWriteFiles に False を指定します。

fso.CopyFile Source, Destination [, OverWriteFiles]

fso.CopyFileの使用例

1つのファイルをコピーする

引数 Destination に既存フォルダ名（パスの区切り文字で終わる）を指定します。以下の例では vba フォルダ内にある test.txt を backup フォルダ内にコピーします。

Sub sample_fs024_01()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim strSrc      As String   'コピー元
    Dim strDst      As String   'コピー先

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'コピー元ファイルパスの設定
    strSrc = "C:¥Users¥xxx¥Desktop¥vba¥test.txt"
    'コピー先フォルダパスの設定
    strDst = "C:\Users\xxx\Desktop\backup\"

    'ファイルのコピー（上書き）
    fso.CopyFile strSrc, strDst

    'オブジェクト変数のクリア
    Set fso = Nothing
End Sub

  Setステートメント

1つのファイルをコピーする（ファイル名変更あり）

引数 Destination にコピー後のファイル名を指定します。 以下の例では、vba フォルダ内にある test.txt を backup フォルダ内にコピーし、 さらに、ファイル名を test_130817.txt へ変更します。

Sub sample_fs024_02()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim strSrc      As String   'コピー元
    Dim strDst      As String   'コピー先

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'コピー元ファイルパスの設定
    strSrc = "C:\Users\xxx\Desktop\vba\test.txt"
    'コピー先ファイルパスの設定（ファイル名変更）
    strDst = "C:\Users\xxx\Desktop\backup\test_130817.txt"

    'ファイルのコピー（上書き）
    fso.CopyFile strSrc, strDst

    'オブジェクト変数のクリア
    Set fso = Nothing
End Sub

  Setステートメント

複数のファイルを1命令でコピーする

引数 Source にワイルドカードを使用してコピーしたいファイル群を表現します。 以下の例では、vba フォルダ内にあるテキストファイルをすべて backup フォルダ内へコピーします。

Sub sample_fs024_03()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim strSrc      As String   'コピー元
    Dim strDst      As String   'コピー先

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'コピー元ファイルパスの設定
    strSrc = "C:\Users\xxx\Desktop\vba\*.txt"
    'コピー先フォルダパスの設定
    strDst = "C:\Users\xxx\Desktop\backup\"

    'ファイルのコピー（上書き）
    fso.CopyFile strSrc, strDst

    'オブジェクト変数のクリア
    Set fso = Nothing
End Sub

  Setステートメント

file.Copyの使用方法

ファイルオブジェクト内にコピー元のファイルパス情報を持っているので、引数に必ず指定するのはコピー先のファイルパスのみです。その他の使用方法は fso.CopyFile に同じです。

file.Copy Destination [, OverWriteFiles]

file.Copyの使用例

1つのファイルをコピーする

引数 Destination に既存フォルダ名（パスの区切り文字で終わる）を指定します。 以下の例では vba フォルダ内にある test.txt を backup フォルダ内にコピーします。

Sub sample_fs024_04()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim fileObj     As Object   'ファイルオブジェクト

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'ファイルオブジェクト取得
    Set fileObj = fso.GetFile("C:\Users\xxx\Desktop\vba\test.txt")

    'ファイルのコピー（上書き）
    fileObj.Copy "C:\Users\xxx\Desktop\backup\"

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set fileObj = Nothing
End Sub

 fso.GetFile  Setステートメント

1つのファイルをコピーする（ファイル名変更あり）

引数 Destination にコピー後のファイル名を指定します。 以下の例では、vba フォルダ内にある test.txt を backup フォルダ内にコピーし、 さらに、ファイル名を test_130817.txt へ変更します。

Sub sample_fs024_05()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim fileObj     As Object   'ファイルオブジェクト

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'ファイルオブジェクト取得
    Set fileObj = fso.GetFile("C:\Users\xxx\Desktop\vba\test.txt")

    'ファイルのコピー（上書き）
    fileObj.Copy "C:\Users\xxx\Desktop\backup\test_130817.txt"

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set fileObj = Nothing
End Sub

 fso.GetFile  Setステートメント

フォルダ内の複数ファイルを1つずつコピーする

指定されたフォルダ内のファイルのうち、Like演算子 を使用して、あるファイル名パターンにマッチするものだけをコピーする例です。以下の例では、ファイル名が”a”と4ケタの数字からなるテキストファイルを backup フォルダへコピーします。

数値4ケタは2種類のワイルドカード（ * および ? ）では表現できません。? は任意の1文字を表すため “a????.txt” としてしまうと “aaaaa.txt” などもコピーの対象となってしまいます。このため、Like演算子 と数字を表す”#”を使用してファイル名の判定を行っています。

Sub sample_fs024_06()
    Dim fso         As Object   'ファイルシステムオブジェクト
    Dim folderObj   As Object   'フォルダオブジェクト
    Dim fileObj     As Object   'ファイルオブジェクト

    'メインオブジェクトの生成
    Set fso = CreateObject("Scripting.FileSystemObject")

    'フォルダオブジェクト取得
    Set folderObj = fso.GetFolder("C:\Users\xxx\Desktop\vba")

    For Each fileObj In folderObj.Files
        'ファイル名判定
        If fileObj.Name Like "a####.txt" Then
            'ファイルのコピー（上書き）
            fileObj.Copy "C:\Users\xxx\Desktop\backup\"
        End If
    Next

    'オブジェクト変数のクリア
    Set fso = Nothing
    Set folderObj = Nothing
    Set fileObj = Nothing
End Sub

 fso.GetFolder For Each…Next Like 演算子  Setステートメント

以下の２つの図はマクロ実行前のvbaフォルダとbackupフォルダの状態です。

上記サンプルマクロを実行すると、aから始まる数値4桁のテキストファイル2つがbackupフォルダにコピーされたことがわかります。

 
ファイルシステムオブジェクトのプロパティ・メソッド
ファイルシステムオブジェクトによるフォルダコピー