セル書式（配置）の設定方法

このページでは、セルの書式設定画面の配置タブに対応するプロパティについて説明します。

配置に関するプロパティの設定

Sub sample6_12()
    With Range("A1")
        '横位置
        .HorizontalAlignment = xlHAlignLeft
        'インデント
        .IndentLevel = 2
        '前後にスペース
        .AddIndent = False
        '縦位置
        .VerticalAlignment = xlVAlignCenter
        '文字の折り返し
        .WrapText = False
        '縮小して全体表示
        .ShrinkToFit = False
        'セルの結合
        .MergeCells = False
        '文字列の向き
        .Orientation = 0
        '文字列の並び(日本語には無意味)
        .ReadingOrder = xlContext
    End With
End Sub

文字の横位置 – HorizontalAlignment プロパティ

文字の横位置は HorizontalAlignment プロパティに下表の定数を設定することで変更することができます。

プロパティ	定数	説明
HorizontalAlignment	xlHAlignGeneral	標準
	xlHAlignLeft	左詰め
	xlHAlignCenter	中央揃え
	xlHAlignRight	右詰め
	xlHAlignFill	繰り返し
	xlHAlignDistributed	両端揃え
	xlHAlignCenterAcrossSelection	選択範囲内で中央
	xlHAlignJustify	均等割り付け

HorizontalAlignment 関連プロパティ

• インデント – IndentLevel プロパティ
  HorizontalAlignment が左詰め、右詰め、均等割り付けの場合に0～15の数値を設定できます。
• 前後にスペース – AddIndent プロパティ
  HorizontalAlignment が均等割り付けの場合にTrueを設定できます。

文字の縦位置 – VerticalAlignment プロパティ

文字の縦位置は VerticalAlignment プロパティに下表の定数を設定することで変更することができます。

プロパティ	定数	説明
VerticalAlignment	xlVAlignTop	上詰め
	xlVAlignCenter	中央揃え
	xlVAlignBottom	下詰め
	xlVAlignDistributed	両端揃え
	xlVAlignJustify	均等割り付け

文字の折り返し – WrapText プロパティ, 縮小して全体表示 – ShrinkToFit プロパティ

文字の折り返しは WrapText プロパティにTrueを設定することで可能になります。縮小して全体表示は ShrinkToFit プロパティにTrueを設定することで可能になります。両方ともTrueの場合は文字の折り返しが優先されます。

Sub sample6_13()
    With Range("A1")
        .Value = "１．折り返しなし、縮小なし"
        .WrapText = False
        .ShrinkToFit = False
    End With

    With Range("A3")
        .Value = "２．折り返しあり、縮小なし"
        .WrapText = True
        .ShrinkToFit = False
    End With

    With Range("A5")
        .Value = "３．折り返しなし、縮小あり"
        .WrapText = False
        .ShrinkToFit = True
    End With

    With Range("A7")
        .Value = "４．折り返しあり、縮小あり"
        .WrapText = True        'こちらが優先されます
        .ShrinkToFit = True
    End With
End Sub

セルの結合・結合解除 – MergeCells プロパティ

セルの結合は結合したいセル範囲を指定して MergeCells プロパティにTrueを設定することで可能になります。逆にFalseを設定すると結合セルが解除されます。

Sub sample6_14_1()
    With Range("A2:C3")
        'レンジ内の最初のセルにだけ値を設定
        .Cells(1).Value = "セルを結合"
        .MergeCells = True
    End With
End Sub

Sub sample6_14_3()
    With Range("A2")    '結合セルのうちの1つを解除すればよい
        .Value = "セルの結合を解除"
        .MergeCells = False
    End With
End Sub

セルの結合範囲の取得 – MergeArea プロパティ

MergeArea プロパティは、結合セルの１つに対してそのセルを含む結合セル全体の範囲を取得します。

Sub sample6_14_2()
    '結合セルのうちの1つを指定すればよい
    MsgBox Range("A2").MergeArea.Address
End Sub

文字列の向き – Orientation プロパティ

文字列の向きはOrientationプロパティに下表の定数を設定することで変更することができます。このプロパティには-90° ～ 90° の角度を整数で設定することも可能です。

文字列の並び – ReadingOrder プロパティ

文字列の向きはReadingOrderに下表の定数を設定することで変更することができます。ただ、この設定は右から左へ記述する言語に対して有効であり、日本語には意味を持ちません。

プロパティ	定数	説明
ReadingOrder	xlContext	対象
	xlRTL	右から左
	xlLTR	左から右