ワークブックのオープン（Open メソッド）

ワークブックを開くには Workbooks コレクションの Open メソッドを使用します。引数の数が多いですが、はじめのうちは FileName だけ覚えておけばよいです。その後必要に応じて他の引数を覚えていくようにしましょう。

Openメソッドの使用方法

Workbooks.Open( FileName _
  [, UpdateLinks] [, ReadOnly] [, Format] [, Password] _
  [, WriteResPassword] [, IgnoreReadOnlyRecommended] _
  [, Origin] [, Delimiter] [, Editable] [, Notify] _
  [, Converter] [, AddToMru] [, Local] [, CorruptLoad] )

一連のチェックをしてからワークブックを開く

引数 FileName だけ指定してワークブックを開く例です。ワークブックを開く前に、既に開かれているかどうか（チェック①）、ファイルが存在するかどうか（チェック②）もチェックしています。

※ワークブック”test.xlsx”は以下のサンプルマクロが組み込まれたブックと同じフォルダ内にあるものとします。

Sub sample_eb083_01()
    Dim TargetFile      As String
    Dim TargetFilePath  As String
    Dim flg_opened      As Boolean
    Dim i               As Integer

    '開きたいファイル名
    TargetFile = "test.xlsx"

    'TargetFileがマクロが組み込まれたブックと
    '同じフォルダにあるものとしてファイルパスを作成。
    TargetFilePath = ThisWorkbook.Path & "¥" & TargetFile

    '★チェック① : 既に開かれていないかチェック
    flg_opened = False
    For i = 1 To Workbooks.Count
        If Workbooks(i).Name = TargetFile Then
            flg_opened = True
            Exit For
        End If
    Next i

    If flg_opened Then
        '既に開かれている場合
        MsgBox "『" & TargetFile & "』は既に開かれています。", _
                vbExclamation
    Else
        '★チェック② : ファイルの存在チェック
        If Dir(TargetFilePath) = "" Then
            'ファイルが見つからない場合
            MsgBox "『" & TargetFile & "』が見つかりません。", _
                    vbExclamation
        Else
            'ファイルが存在している場合はブックを開く
            Workbooks.Open TargetFilePath
            MsgBox "『" & TargetFile & "』を開きました。", _
                    vbInformation
        End If
    End If
End Sub

 ThisWorkbook  ワークブックの名前とパス  ワークブックCount
 For…Next Exitステートメント MsgBox関数 Dir関数

ワークブック”test.xlsx”の配置が正しければ、初回のマクロ実行でこのブックを正常にオープンできるはずです。

“test.xlsx”を開いた状態で、再度マクロを実行すると以下のエラーが表示されます。

“test.xlsx”が存在しなかったり、配置場所に誤りがあると以下のメッセージが表示されます。

 ワークブックを保存する ワークブックを保存して閉じる