このページでは、セルの書式設定画面の罫線タブに対応するプロパティについて説明します。
Borders コレクションの使用方法
Borders コレクションの引数に操作対象の組み込み定数を指定することで、その操作対象を指定します。罫線オブジェクトには、スタイル、太さ、色の値を取得・設定できるプロパティが用意されています。
Sub sample6_19()
'罫線（右斜め上）
With Range("B2").Borders(xlDiagonalUp)
'罫線のスタイル
.LineStyle = xlContinuous
'罫線の太さ
.Weight = xlHairline
'罫線の色
.ColorIndex = xlAutomatic
End With
'罫線（上）
With Range("C2").Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlThin
.Color = vbRed
End With
'罫線（右斜め下）
With Range("D2").Borders(xlDiagonalDown)
.LineStyle = xlContinuous
.Weight = xlMedium
.Color = vbGreen
End With
'罫線（右）
With Range("D3").Borders(xlEdgeRight)
.LineStyle = xlContinuous
.Weight = xlThick
.Color = vbBlue
End With
'罫線（下）
With Range("B3:D3").Borders(xlEdgeBottom)
.LineStyle = xlDash
.Weight = xlThin
'RGB関数による色の指定
.Color = RGB(255, 102, 0)
End With
'罫線（左）
With Range("B3").Borders(xlEdgeLeft)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With
'罫線（上、右、下、左、内側水平、内側垂直）
With Range("B5:D7").Borders
.LineStyle = xlDouble
.Weight = xlThick
.ColorIndex = xlAutomatic
End With
End Sub
操作対象の罫線 – Borders コレクション
操作対象の罫線は Borders コレクションによりコントロールします。操作対象の罫線を指定したら、そのスタイルや色のプロパティを設定します。
| オブジェクト | 操作対象の罫線 |
|---|---|
| Borders | 上、右、下、左、 内側水平、内側垂直 |
| Borders(xlEdgeTop) | 上 |
| Borders(xlEdgeRight) | 右 |
| Borders(xlEdgeBottom) | 下 |
| Borders(xlEdgeLeft) | 左 |
| Borders(xlInsideHorizontal) | 内側水平 |
| Borders(xlInsideVertical) | 内側垂直 |
| Borders(xlDiagonalDown) | 左上から右下 |
| Borders(xlDiagonalUp) | 左下から右上 |
罫線のスタイル – Borders.LineStyle, .Weight プロパティ
罫線のスタイルは Borders.LineStyle および Borders.Weight プロパティに下表の定数を設定することで変更することができます。
| プロパティ | 定数 | 説明 |
|---|---|---|
| Borders.LineStyle | xlNone または xlLineStyleNone |
線なし |
| xlDash | 破線 | |
| xlDashDot | 一点鎖線 | |
| xlDashDotDot | 二点鎖線 | |
| xlDot | 実線 | |
| xlDot | 点線 | |
| xlSlantDashDot | 斜め破線 | |
| xlDouble | 2本線 | |
| Borders.Weight | xlHairline | 細線 |
| xlThin | 通常線 | |
| xlMedium | 中太線 | |
| xlThick | 太線 |
罫線の色 – Borders.Color Borders.ColorIndex プロパティ
罫線の色は Borders.Color または Borders.ColorIndex プロパティのどちらかを設定します。それぞれ色の指定の仕方が異なりますので、扱いやすい方を使用しましょう。
- Borders.Color ・・・ 色定数またはRGB値で色を指定
- Borders.ColorIndex ・・・ カラーパレットのインデックス値で色を指定
※罫線の色を自動設定する場合は定数を指定
| プロパティ | 定数・値 | 説明 |
|---|---|---|
| Borders.Color | vbBlack | 黒色 |
| vbRed | 赤色 | |
| vbGreen | 緑色 | |
| vbBlue | 青色 | |
| vbYellow | 黄色 | |
| vbMagenta | マゼンタ | |
| vbCyan | シアン | |
| vbWhite | 白色 | |
| RGB関数の戻り値 ※R,G,Bは0～255の範囲 |
RGB値（Long型） | |
| Borders.ColorIndex | xlAutomatic または xlColorIndexAutomatic |
自動設定 |
| 1～56の整数値 | カラーパレットのインデックス値 ※カラーパレットの一覧 |