cells を使った別ブックへの転記について

投稿者 : 浜松餃子     投稿日時 : 2025/03/06(Thu) 22:23:19     OS : 未指定     EXCEL : 未指定

---

はじめまして。
初心者です。よろしくお願いいたします。

開いている二つのブックにおいて、ブックからもう一方のブックにcells を使って転記をしたいのですが、エラーが出ます
（アプリケーション定義またはオブジェクションの定義エラーです（エラーコード1004））。
cellsではなくrange("a1:b2")等では転記できます。
cellsで変数を指定したいのでrange ではなくcellsでの転記を考えています(下記はテストなので変数の箇所は数値にしています）。

下記となっていますが、ご教示お願い致します。

------------------------------------------------------------

Sub 貼り付けテスト()

Dim wb1 As Workbook

Set wb1 = Workbooks("貼り付け先.xlsx")
wb1.Activate

Dim wb2 As Workbook

Set wb2 = Workbooks("元データ.xlsm")
wb2.Activate

wb1.Sheets("sheet1").Range(Cells(1, 1), Cells(3, 2)).Value = wb2.Sheets("sheet1").Range(Cells(1, 1), Cells(3, 2)).Value

MsgBox "貼り付け完了しました!"

End Sub

投稿者 : さんこう     投稿日時 : 2025/03/06(Thu) 22:41:19

---

参考になれば。

＜range(cells cells) エラー＞
https://www.google.com/search?q=range%28cells+cells%29+%E3%82%A8%E3%83%A9%E3%83%BC

投稿者 : てらてら     投稿日時 : 2025/03/07(Fri) 06:13:15

---

こんにちは。

Rangeの中のCellsにも、ブック指定、シート指定しないとダメです。

wb1.Sheets("sheet1").Range(wb1.Sheets("sheet1").Cells(1, 1), wb1.Sheets("sheet1").Cells(3, 2)).Value = _
wb2.Sheets("sheet1").Range(wb2.Sheets("sheet1").Cells(1, 1), wb2.Sheets("sheet1").Cells(3, 2)).Value

冗長になってしまうので、普通は互いのシートを変数に代入して記述します。

それと、ブックやシートを指定する場合は、wb1.Activate　などは不要です。

投稿者 : 浜松餃子     投稿日時 : 2025/03/07(Fri) 08:10:18

---

さんこうさん、てらてらさん、ありがとうございました。

cellsにブック指定、シート指定で無事に転記できました。

たしかに冗長なので、次はシート名に変数を代入してやってみます。

ありがとうございました。

投稿者 : 浜松餃子     投稿日時 : 2025/03/07(Fri) 23:04:05

---

てらてらさん

シート名に変数を代入して無事に転記できました。

ありがとうございました。

----------------------------------------------------------

Dim wb1 As Workbook
Set wb1 = Workbooks("貼り付け先.xlsx")

Dim ws1 As Worksheet
Set ws1 = wb1.Worksheets("sheet1")

Dim wb2 As Workbook
Set wb2 = Workbooks("元データ.xlsm")

Dim ws2 As Worksheet
Set ws2 = wb2.Worksheets("sheet1")

ws1.Range(ws1.Cells(1, 1), ws1.Cells(3, 2)).Value = ws2.Range(ws2.Cells(1, 1), ws2.Cells(3, 2)).Value

MsgBox "貼り付け完了しました!

投稿者 : てらてら     投稿日時 : 2025/03/08(Sat) 04:14:58

---

こうすれば、もっと簡単に書ける。

Dim ws1 As Worksheet
Set ws1 = Workbooks("貼り付け先.xlsx").Worksheets("sheet1")

Dim ws2 As Worksheet
Set ws2 = Workbooks("元データ.xlsm").Worksheets("sheet1")

投稿者 : 浜松餃子     投稿日時 : 2025/03/08(Sat) 17:40:38

---

てらてらさん、ありがとうございました。