指定した行範囲をループする方法

投稿者 : るふぃ     投稿日時 : 2025/02/08(Sat) 01:12:57     OS : 未指定     EXCEL : 未指定

---

下記画像のように、縦に日付が続くシートがあります。
この日付列の第1週だけをループするマクロを作りたいのですが、ご教授いただけないでしょうか？
イメージは、4行目～10行目ループした後step25し、35行目～41行目ループした後step25し.....最終行まで繰り返すです。
そもそも無理なことなのかもしれませんが、よろしくお願いします。

画像：https://ibb.co/s9VZQ1CX

作成マクロ：

Sub macro()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim count As Long
    Dim test As String

    test = "大阪"
    
    Set ws = ThisWorkbook.ActiveSheet
    
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    
    count = 0
    
    For i = 1 To lastRow
        If ws.Cells(i, 2).Value = test Then
            count = count + 1
        End If
    Next i
 
    ws.Cells(1, 3).Value = count
End Sub

投稿者 : とおりすがり     投稿日時 : 2025/02/08(Sat) 04:59:16

---

Forステートメントのいろんな使い方を覚えましょう

Sub sample()
  For i = 4 To Cells(Rows.Count, "B").End(xlUp).Row Step 31
      For j = i To i + 6
          Debug.Print j; Cells(j, "B")
      Next
  Next
End Sub

投稿者 : ピロリ     投稿日時 : 2025/02/08(Sat) 11:33:45

---

■[質問] るふぃさん（2025-02-08 01:12:57）の記事
＞ イメージは、4行目～10行目ループした後step25し、35行目～41行目ループした後step25し.....最終行まで繰り返す
１つのループで上のような考え方なら↓下のようにも記述できますが、[返信 1] とおりすがりさんの２重ループの方が
分かり易いコードですね。

Sub macro()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim count As Long
    Dim test As String
    Dim d As Long                           'これを追加
    
    test = "大阪"
    
    Set ws = ThisWorkbook.ActiveSheet
    lastRow = ws.Cells(ws.Rows.count, "A").End(xlUp).Row
    
    count = 0
    d = 1                                   'これを追加
    For i = 4 To lastRow                    '4行目からループさせましょう
        If ws.Cells(i, 2).Value = test Then
            count = count + 1
        End If
        
        If d = 7 Then                       'ここから、
            i = i + 24
            d = 0
        End If
        d = d + 1                           'ここまで追加
    Next i
    
    ws.Cells(1, 3).Value = count
End Sub

投稿者 : 通行人     投稿日時 : 2025/02/09(Sun) 14:40:21

---

CountIf関数を使って、こんな感じでも。

Sub macro2()
    Dim ws As Worksheet
    Dim i As Long
    Dim count As Long
    Dim test As String
    
    test = "大阪"
    Set ws = ThisWorkbook.ActiveSheet
    count = 0
    For i = 4 To ws.Cells(Rows.count, "A").End(xlUp).Row Step 31
        count = count + WorksheetFunction.CountIf(ws.Cells(i, "B").Resize(7, 1), test)
    Next i
    ws.Cells(1, "C").Value = count
End Sub

投稿者 : るふぃ     投稿日時 : 2025/02/12(Wed) 12:12:51

---

とおりすがり様
ピロリ様
通行人様

おかげさまで解決いたしました。
ありがとうございます。