エクセルVBAを使って、指定フォルダ内の拡張子を変更したい。 doc→docx, ppt→pptx

投稿者 : まる     投稿日時 : 2024/10/23(Wed) 15:14:28     OS : Windows 11     EXCEL : Office 365

---

古いファイルの拡張子を一つずつ変更していますが、エクセルVBAを使って変更できないでしょうか。

①任意のフォルダ内のppt,wordを一括でdoc→docx,ppt→pptxに変更し、上書き保存が可能なコマンドを教えて欲しい

投稿者 : りんく     投稿日時 : 2024/10/23(Wed) 16:34:18

---

Excelの旧バージョン.xlsファイルを新バージョンの.xlsxファイルに変換するツールを作成してみた
https://qiita.com/yamaguchi50/items/90dabb95a6486140edcb

投稿者 : らたたた     投稿日時 : 2024/10/23(Wed) 23:24:26

---

拡張子を変えただけで、ファイルの性格が変わるものではない
下手するとファイルが壊れたりする
一個一個ファイルを開いて保存し直す必要があると思います

投稿者 : tek     投稿日時 : 2024/10/24(Thu) 08:17:53

---

上書きでなく、別のファルダへの保存としていますが、パワーポイント用の一例を作成してみました。
ワードはマクロの記録ができるので利用するか他の回答者を待ちましょう。

Sub ppt2pptx()
    Dim fromPath As String
    Dim toPath As String
    Dim App As Object
    Dim ppt As Object
    Dim fn As String
    Dim 拡張子 As String

    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "pptのフォルダを指定ください"
        If Not .Show Then Exit Sub
        fromPath = .SelectedItems(1) & "\"
    End With
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "pptxのフォルダを指定ください"
        If Not .Show Then Exit Sub
        toPath = .SelectedItems(1) & "\"
    End With
    
    fn = Dir(fromPath & "*.ppt")
    If fn = "" Then Exit Sub
    Set App = CreateObject("PowerPoint.Application")
    Do While fn <> ""
        If LCase(fn) Like "*.ppt" Then
            Set ppt = App.Presentations.Open(fromPath & fn)
            If ppt.HasVBProject Then
                拡張子 = "m"
            Else
                拡張子 = "x"
            End If
            ppt.SaveAs toPath & fn & 拡張子
            ppt.Close
        End If
        fn = Dir()
    Loop
    App.Quit
End Sub