条件付き書式で色付けしたセルの合計を求める

投稿者 : 南     投稿日時 : 2024/10/10(Thu) 20:14:21     OS : 未指定     EXCEL : 未指定

---

L3セルからEB3セルの範囲を条件付き書式で、条件に合えば黄色に色付けするようにしています。
色の取得は

Sub TEST()
    Debug.Print Range("L3").DisplayFormat.Interior.ColorIndex
End Sub

で取得し、イミディエイトウィンドウで6でした。

これを元にL3セルからEB3セルの範囲のColorIndex6の数の合計をK3セルに求めたくて下記コードを作成しました。
結果は範囲内で色付けされたセルがあるのに、ゼロでした。
お気づきの箇所あればご教授いただけないでしょうか。よろしくお願いします。

Sub ColorIndex6のtest()
    Dim rng As Range
    Dim cell As Range
    Dim total As Double

    ' L3からEB3までの範囲を設定
    Set rng = Range("L3:EB3")
    
    ' 合計を初期化
    total = 0
    
    ' 各セルをループしてColorIndexを確認
    For Each cell In rng
        If cell.Interior.ColorIndex = 6 Then ' ColorIndexが6の場合
            total = total + cell.Value ' 値を合計
        End If
    Next cell
    
    ' K3セルに合計を出力
    Range("K3").Value = total
End Sub

投稿者 : ピロリ     投稿日時 : 2024/10/11(Fri) 00:43:43

---

Sub TEST() に記述している「.DisplayFormat」プロパティが漏れているからでしょう。

　If cell.Interior.ColorIndex = 6 Then
　　　　　　　↓
　If cell.DisplayFormat.Interior.ColorIndex = 6 Then

投稿者 : 南     投稿日時 : 2024/10/12(Sat) 09:11:14

---

ありがとうございます。おかげさまで解決しました。